Results 1 to 2 of 2

Thread: EasyUO Provocation script for the new Barding area

  1. #1

    Riath's PROVO v1.3 (EasyUO) Provocation trainer for Oasis Barding area

    Code:
    ;Provocation Trainer for the new Barding area in the Paradise Found Training Oasis.
    ;Written by Riath D'Ersines.
    ;Many thanks to Damara for setting this area up and to Religio for providing an idea to be improved upon.
    ;
    ;VERSION 1.3 - Fixed scanning behavior. Credit to Cid for finding the issue.
    ;VERSION 1.2 - First public release
    ;
    ;INSTRUCTIONS: Ensure you're in front of the proper targets in order to gain skill at your level.
    ;              For corpse cleanup to work, you must be within two tiles of the target.
    ;              And no, even though it's claiming corpses, you're not gaining any platinum. Nice try.
    ;              DO NOT USE EXCEPTIONAL INSTRUMENTS! It throws off the barding difficulty. Buy some from an NPC if need be.
    
                       ;A value of 20 equals 1 second.
    set %objdelay 15   ;Increase this number if you get object use delay errors.
    set %castdelay 15  ;Increase this number if you need more delay between kills.
    set %successdelay 10s
    set %faildelay 6s
    
    ;This section is the initial target setup.
             display ok Select your target.
             set #targcurs 1
             settarg:
             if #targcurs = 1
                 goto settarg
             finditem #ltargetid G_3
             set %target #findtype
    
    ;Beyond this point is the actual script itself.
    mainloop:
             set %jstart #jindex + 1
             gosub provo
             set %jend #jindex + 2
             wait %objdelay
             gosub scan
             wait %skilldelay
             gosub skillcheck
             goto mainloop
             
    sub provo
             finditem %target 1 G_3
             set %target1 #findid
             finditem %target 2 G_3
             set %target2 #findid
             event macro 13 22
             set #ltargetid %target1
             target 3s
             event macro 22
             set #ltargetid %target2
             target 3s
             event macro 22
             return
    
    sub scan
             for %i %jstart %jend
             {
             scanjournal %i
             if succeeds in #journal
                  {
                  gosub kill
                  set %skilldelay %successdelay
                  }
             else
                  set %skilldelay %faildelay
             if increased in #journal
                  event macro 1 0 [e woohoo
             }
             return
    
    sub kill
             set #ltargetid %target1
             event macro 15 29
             target 3s
             event macro 22
             wait %castdelay
             set #ltargetid %target2
             event macro 15 29
             target 3s
             event macro 22
             wait %objdelay
             gosub cleanup
             return
             
    sub cleanup
             finditem YFM G_2
             while #findkind = 1
                  {
                  set #ltargetid #findid
                  event macro 1 0 [cl
                  target 3s
                  event macro 22
                  wait %objdelay
                  set #findindex #findindex + 1
                  }
             return
    
    sub skillcheck
             chooseskill prov
             if #skill >= 1000
                  {
                  event macro 1 0 [e applaud
                  display ok Congratulations! You're now at or beyond GM Provocation. This script will not help you any further. Halting!
                  halt
                  }
             return
    Attached Files Attached Files
    Last edited by Riath D'Ersines; 12-23-2016 at 09:53 AM. Reason: Update

  2. #2
    Thank you, Riath, for the suggestion of hosting a barding system at the Training Oasis, and for the many hours testing, adjusting, retesting the animals, and now for both the provo and discord EUO scripts. They do work, I have watched Riath go from zip to GM in a matter of hours, rather than days. However, something to be aware of, it works when attended rather than strictly AFK.

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •